Regulator triaca

[Zagor]

oke super....znači mogu na ovo direktno spojiti lemilicu ?...međutim pitanje je kakva će biti regulacija, dali će se dati relativno fino i ugodno podešavati ili ?
i molio bih te da mi pošalješ hex na pm...hvala puno

[Drago_Zg]

Kakva će biti regulacija?
U svakom pogledu regulacija temperature lemnih postaja (kako to u prodaji nazivaju), a treba biti lemila, jer nas to interesira, najtočnije se obavlja sa Thermo regulatorom. To podrazumijeva thermo sonda što bliže vrhu lemila i što manju temperaturnu razliku uključenja i isključenja thermo regulatora. Time dobijemo dobru osjetljivost i dobru preciznost.
Regulacija temperature lemila?
Sa regulatorom triaca bazira se na činjenici da možemo smanjenjem napona na grijaču, dobiti grijač manje snage.Tako da svaki grijač manje snage, razvija manju temperaturu vrha lemilice u nekoj približno linearnoj ovisnosti. U koliko nemamo nekih izričitih zahtjeva, triak regulatora u potpunosti zadovoljava držanje konstantne temperature lemila sa vizualnom kontrolom.
Jasno, to podrazumijeva i naknadno namještanje snage ( temperature).

[Zagor]

@Drago zahvaljujem , to sam i pretpostavljao , mislio sam nešto ovako i sam napraviti koristeći At89c2051 i njegov analogni komparator (planirao sam regulaciu izvesti potenciometrom) , ali nikako da se nađe vremena za to...eto pa zahvaljujem na ovome , izuzetan rad

[Drago_Zg]

Regulator triaca sa PIC 16F84A, koristi istu tiskanu pločicu,samo se mora odspojiti pin 3 od pina 4, tako da ostane pin 4 PIC 16F84A sa svojim otporom 4K7 prema plus napajanju. Naravno ostaju i funkcijski otpornici 220 E. Hex file:

[Drago_Zg]

Assemblerski kod za regulator tiaca:

; TRIAC CONTROL
; Regulacija snage moguca od 1% do 99% kod 50 Hz.
; -odabir poluvalni ili punovalni regulator
; -izbor mekog START/STOP-a
; -tipka za ukljucenje
; -dvije tipke za +/-
; -spora pa brza promjena prikaza
; -prikaz postotka za 2*7 segmentnom LED-u
; -programirano VII 2000
; Frekvencija oscilatora je 4MHz
;**********************************************************************
list p=16F84A
#include <p16F84A.inc>

__CONFIG _CP_OFF & _WDT_ON & _PWRTE_ON & _XT_OSC

;**********************************************************************
;definiranje asembliranja

TEST_RS EQU 0 ;
TestFlag EQU 1 ;0-stvarni rad
;1-unos porta B u Flag
;**********************************************************************
;----------------------------------------------------------------------
; Definiranje varijabli
;----------------------------------------------------------------------
PC EQU 02 ;programski brojac
PORT_A EQU 05 ;Port A
PORT_B EQU 06 ;Port B
Ulaz EQU 05 ;PORT_A
Temp EQU 014h ;privremeni registar
Temp1 EQU 015h ;privremeni registar
Rad EQU 016h ;ulaz signala
Snaga EQU 017h
;----------------------------------------------------------------------
Flag EQU 0Ch ;trenutna stanja po bitovima
;0-Otpustena tipka
;1-Up
;2-Down
;3-Off/On 0-Off pogledaj bitove PORT-a B
; 1-On
;4-Full
;5-Soft
;6-Tog
Mem EQU 07 ;7-Mem
;----------------------------------------------------------------------
Disp EQU 0D ;registar za prikaz postotka
Brid EQU 0E ;privremeni registar
Loop1 EQU 0F ;privremeni registar

MSD EQU 10 ;teza znamenka
LSD EQU 11 ;laksa znamenka

DrTi EQU 12 ;brojanje prolaza preko pritisnute tipke
BrDrTi EQU 13 ;brojanje brzog prolaza preko pritisnute tipke
NStack EQU 1F ;registar za umjetni Call

Max EQU .99 ;maksimalno kasnjenje okidanja tiristora/triaka
Min EQU .0 ;minimalno kasnjenje okidanja tiristora/triaka
AkTi EQU .40 ;potreban broj prolaza za normalnu izmjenu
BrAkTi EQU .5 ;potreban broj prolaza za ubrzanu izmjenu
;----------------------------------------------------------------------
; Bitovi porta A
;----------------------------------------------------------------------
Sinh EQU 1 ;ulaz sinhronizacije mreze
MaskSinh EQU B'00000010' ;Sinh je 1. bit
MaskSinC EQU B'11111101' ;Sinh je 1. bit
Out EQU 0 ;izlaz na pobudu
;----------------------------------------------------------------------
; Bitovi porta B
;----------------------------------------------------------------------
Up EQU 1 ;0-povecaj snagu
;1-nije pritisnuta tipka
Down EQU 2 ;0-smanji snagu
;1-nije pritisnuta tipka
OffOn EQU 3 ;togle OFF/ON
Full EQU 4 ;0-poluvalni regulator
;1-punovalni regulator
Soft EQU 5 ;0-meki START/STOP
;1-brzi START/STOP
Tog EQU 6 ;togle OFF/ON
;===================================================================
ORG 010h
;**********************************************************************
;= Znamenka ========================================================
;===================================================================
Znam
ADDWF PC,1
RETLW 0BE ;Broj=00
RETLW 084 ;Broj=01
RETLW 0EA ;Broj=02
RETLW 0EC ;Broj=03
RETLW 0D4 ;Broj=04
RETLW 07C ;Broj=05
RETLW 07E ;Broj=06
RETLW 0A4 ;Broj=07
RETLW 0FE ;Broj=08
RETLW 0FC ;Broj=09
;End Sub
;= Inicijalizacija =================================================
;===================================================================
Init
CLRF PORT_A
BCF STATUS,RP0
MOVLW B'11111110'
MOVWF PORT_A
BSF STATUS,RP0
MOVLW B'11111110' ;postavljanje portova
Movwf PORT_A ;TRISA
BCF STATUS,RP0
MOVLW B'11111111' ;postavljanje portova
Movwf PORT_B
BSF STATUS,RP0
MOVLW B'11111111' ;postavljanje portova
Movwf PORT_B

BSF STATUS,RP0
MOVLW B'00000000' ;postavljanje portova
Movwf INTCON

CLRF 1
CLRF DrTi
CLRF BrDrTi
BSF STATUS,RP0
MOVLW B'11111010'
Movwf TMR0
BCF STATUS,RP0
CLRWDT
RETLW 0
;End Sub
;
;= Odmah kod ukljucenja na napajanje ===============================
;===================================================================
Uklj
uk_1 BTFSC Ulaz,Sinh
GOTO uk_1
uk_2 BTFSS Ulaz,Sinh
GOTO uk_2
BCF Flag,Mem
Movlw Max
Movwf Snaga
Movwf Rad
CLRWDT

RETLW 0
;End Sub
;= Pauza ===========================================================
;===================================================================
Delay1
movlw .29

movwf Loop1
Delay decfsz Loop1,f
goto Delay
retlw 0
;End Sub
;= Tipke ===========================================================
;===================================================================
Tipke
BSF STATUS,RP0
Movlw B'00001110'
Movwf PORT_A ;Tris A

Movlw B'11111110'
Movwf PORT_B ;Tris B
BCF STATUS,RP0

BSF PORT_B,0 ;dozvola citanja tipki

BCF Flag,0 ;provjera da li je tipka bila pustena

Movf PORT_B,W
Movwf Temp

Btfsc Temp,Up
Goto Ti_1
Call Ti_Po ;usporava rad tipki
Movwf Temp1
Btfss Temp1,0
Goto Ti_1
Decf Snaga,F

Movlw Min
Movwf Temp1
Incf Temp1,W ;usporedba
Subwf Snaga,W
Btfss STATUS,C
Incf Snaga,F

Btfss Flag,OffOn
Goto Ti_2
Movf Snaga,W
Movwf Rad
Ti_1
Btfsc Temp,Down
Goto Ti_2
Call Ti_Po ;usporava rad tipki
Movwf Temp1
Btfss Temp1,0
Goto Ti_2
Incf Snaga,F

Movlw Max
Movwf Temp1
Movf Snaga,W ;usporedba
Subwf Temp1,W
Btfss STATUS,C
Decf Snaga,F

Btfss Flag,OffOn
Goto Ti_2
Movf Snaga,W
Movwf Rad
Ti_2
Btfsc Temp,OffOn ;da li je pritisnuta tipka (0)?
Goto Ti_4 ;ne-postavi Tog u 1 i zavrsi
BTFSS Flag,Tog ;da-da li je Tog 1
goto Ti_5 ;ne-zavrsi

BCF Flag,Tog ;da-postavi Tog u 0
BTFSC Flag,OffOn ;promjeni stanje OffOn-a
goto Ti_3
BSF Flag,OffOn
goto Ti_5
Ti_3 BCF Flag,OffOn
goto Ti_5
Ti_4 BSF Flag,Tog
Ti_5
BCF Flag,Full ;
Btfss Temp,Full ;da li je Full pritisnut
BSF Flag,Full ;da-postavi Flag,Full u 1

BCF Flag,Soft ;
Btfss Temp,Soft ;ne-a da li je Soft pritisnut
BSF Flag,Soft ;da-postavi Flag,Soft u 1

Btfss Flag,0 ;provjera da li je tipka bila pustena
CLRF BrDrTi
RETLW 0
;End Sub
;= Brojanje potrebnih prolaza za promjenu stanja ====================
;===================================================================
Ti_Po
BSF Flag,0 ;za provjeru da li je tipka bila pustena
Movlw BrAkTi
Subwf BrDrTi,W ;usporedba
Btfss STATUS,C
Goto Ti_Po_1
Movlw BrAkTi
Goto Ti_Po_2

Ti_Po_1 Movlw AkTi
Ti_Po_2 Subwf DrTi,W ;usporedba
Btfsc STATUS,C
Goto Ti_Po_3
Incf DrTi,F
RETLW 0
Ti_Po_3 CLRF DrTi
Incf BrDrTi,F
RETLW 1
;End Sub
;= Prikaz ==========================================================
;===================================================================
Prikaz
BSF STATUS,RP0
Movlw B'00000000'
Movwf PORT_B ;Tris B
BCF STATUS,RP0


Movlw .100
Movwf Temp
Movf Snaga,W
Subwf Temp,F
Movf Temp,W
Call Bin2BCD
Btfsc Flag,Mem
Goto Pr_1
Bsf Flag,Mem
Movf LSD,W
Call Znam
Movwf PORT_B
BSF PORT_A,3

BSF STATUS,RP0
Movlw B'00000110'
Movwf PORT_A ;Tris A
BCF STATUS,RP0

Goto Pr_2
Pr_1 Bcf Flag,Mem
Movf MSD,W
Call Znam
Movwf PORT_B
BSF PORT_A,2

BSF STATUS,RP0
Movlw B'00001010'
Movwf PORT_A ;Tris A
BCF STATUS,RP0
Pr_2
RETLW 0
;End Sub
;= Meki START/STOP =================================================
;===================================================================
Meki BTFSC Flag,OffOn
GOTO M_1
BTFSC Flag,Soft
GOTO M_2
Movlw Max
Movwf Temp
Decf Temp,F
Movf Rad,W
Subwf Temp,W
Btfsc STATUS,C
Goto M_3
Retlw 0
M_2 Movlw Max
Movwf Rad
Retlw 0
M_1 BTFSS Flag,Soft
Goto M_4
Movf Snaga,w
Movwf Rad
Retlw 1
M_4 Decf Rad,W
Movwf Temp
Movf Snaga,W
Subwf Temp,W
Btfsc STATUS,C
Decf Rad,F
Retlw 1
M_3 Incf Rad,F
RETLW 1
;End Sub
;= Puls ============================================================
;===================================================================
Puls
Movf Rad,W
Movwf Temp
BCF PORT_A,0
Pu_1 Call Delay1
decfsz Temp,f
Goto Pu_1

MovLW .2
Movwf Temp
BSF PORT_A,0
Pu_2 Call Delay1
decfsz Temp,f
Goto Pu_2
BCF PORT_A,0

RETLW 0
;End Sub
;= Binarno u BCD 8 bita ============================================
;===================================================================
Bin2BCD
Clrf MSD
Movwf LSD
Bi_1 Movlw .10
Subwf LSD,W
Btfss STATUS,C
Goto Bi_2
Movwf LSD
Incf MSD,F
Goto Bi_1
Bi_2 RETLW 0
;End Sub
;*******************************************************************
;Glavni dio
;*******************************************************************
Main
Call Init
Call Uklj
;-----------------------------------------------------------
;Pocetak
;-----------------------------------------------------------
Start MOVF Ulaz,W
XORWF Flag,W
AndLW MaskSinh
BTFSC STATUS,Z
GOTO Start
Ma_1 BTFSC Flag,Sinh
goto Ma_2
BSF Flag,Sinh
goto Ma_3
Ma_2 BCF Flag,Sinh
CLRWDT
Ma_3 Call Tipke
CLRWDT
Call Prikaz
CLRWDT
Call Meki
CLRWDT
Movwf Temp
Btfss Temp,0
Goto Ma_5
Btfss Flag,Full ;da li je polu/punovalno
Goto Ma_4
Btfsc Flag,Mem ;da li je ras/pad poluperioda
Goto Ma_5

CLRWDT
Ma_4 Call Puls
Ma_5 GOTO Start
;***********************************************************
ORG 004h
GOTO Main
END

[Drago_Zg]

For mr kovacslajcsi

Software is OK if you use the HEX 16F84A.
The problem with the right work is below:
Triac controller with PIC 16F84
You must disconnect pin 3 of the 4 pins, so it stays pin 4
with resistance to 4K7 plus power.
Pin 3 is fr*e.
Function only set resistor R12 or R13 only.
Do you want soft or hard start and half-wave and sine voltage.
It is desirable to send a picture of his work in the topic Triac controller.

Thank you for your cooperation.